stopdesign.cn

/**
     * @author      chenqian
     * @contact     yesterday[at]gmail.com
     * @URI         www.stopdesign.cn
*/

package  
{
    import flash.display.*;
    import flash.events.*;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class MouseGesture extends Sprite
    {
        public static const GESTURE_UP:String="GESTURE_UP";
        public static const GESTURE_RIGHT:String="GESTURE_RIGHT";
        public static const GESTURE_DOWN:String="GESTURE_DOWN";
        public static const GESTURE_LEFT:String="GESTURE_LEFT";
        // the color of the drawing line
        public var lineColor:Number;    
        // the size of the drawing line         
        public var lineSize:Number;                                     
        // where the mouse start drawing
        private var _startPoint : Point;
        // where the mouse stop drawing
        private var _newPoint : Point;
        // the drawing direction
        private var _direction : String;
        // the drawing line
        private var _drawLine : Sprite;
        
        public function MouseGesture(...rest){
            trace("mouse gesture init")
            // default mouse gestrue line color and size
            lineColor=0xFF0000;
            lineSize= 2;
            
            // parse parameters
            if(rest[0] != null){    
                lineColor = rest[0];
            
            }
            if(rest[1] != null){
                lineSize=rest[1];   
            }
            
            //add the shape, used for drawing the gesture
            var child:Shape = new Shape();
            child.graphics.beginFill(0x000000);
            child.graphics.lineStyle(0, 0xFFFFFF);
            child.graphics.drawRect(0, 0, 1600, 1600);
            child.graphics.endFill();
            addChild(child);
            child.alpha=0;
            _drawLine = new Sprite();
            addChild( _drawLine );
            addEventListener( MouseEvent.MOUSE_DOWN , mouseDownHandler );
        }
        // set the gesture color
        public function setLineColor(c:Number):void{
            lineColor=c;
        }
        // set the gesture size
        public function setLineSize(s:Number):void{
            lineSize=s;
        }
        
        // fire when user press mouse down
        private function mouseDownHandler( e:MouseEvent ):void
        {
            
            var _color : Number = lineColor;
            var _size : Number = lineSize;
            _startPoint = new Point( mouseX , mouseY );
            _drawLine.graphics.lineStyle( _size , _color , 1.0 );
            _drawLine.graphics.moveTo( _startPoint.x , _startPoint.y );
            addEventListener( MouseEvent.MOUSE_MOVE , mouseMoveHandler );
            addEventListener( MouseEvent.MOUSE_UP , mouseUpHander );
        }
        
        // fire when user move the mouse
        private function mouseMoveHandler( e:MouseEvent ):void
        {
            _newPoint = new Point(  mouseX , mouseY );
            var _distance : Number = Point.distance( _startPoint , _newPoint );     
            _drawLine.graphics.lineTo( _newPoint.x , _newPoint.y );
        }
        
        // fire when user's mouse is up
        private function mouseUpHander( e:MouseEvent ):void
        {
            detectDir();                        
            _drawLine.graphics.clear();
            removeEventListener( MouseEvent.MOUSE_MOVE , mouseMoveHandler );
            removeEventListener( MouseEvent.MOUSE_UP , mouseUpHander );
        }
        
        /* detecting the mouse move direction */
        private function detectDir():void 
        {
            var _vector:Point = _newPoint.subtract( _startPoint );
            var _angle : Number = Math.atan2( _vector.y , _vector.x )  * 180 / Math.PI;
            // move down
            if ( _angle >= 45 && _angle < 125 ){
                dispatchEvent(new Event(MouseGesture.GESTURE_DOWN,true));
                removeEventListener( MouseEvent.MOUSE_MOVE , mouseMoveHandler );
                removeEventListener( MouseEvent.MOUSE_UP , mouseUpHander );             
            }   
            // move left
            else if ( _angle >= 125 || _angle < -125 ){
                dispatchEvent(new Event(MouseGesture.GESTURE_LEFT,true))        
                removeEventListener( MouseEvent.MOUSE_MOVE , mouseMoveHandler );
                removeEventListener( MouseEvent.MOUSE_UP , mouseUpHander );             
                
            }   
            // move right
            else if ( _angle >= -45 && _angle < 45 ){
                dispatchEvent(new Event(MouseGesture.GESTURE_RIGHT,true))
                removeEventListener( MouseEvent.MOUSE_MOVE , mouseMoveHandler );
                removeEventListener( MouseEvent.MOUSE_UP , mouseUpHander );             
                
            }   
            // move up
            else if ( _angle >= -125 && _angle < -45 ){
                dispatchEvent(new Event(MouseGesture.GESTURE_UP,true))
                removeEventListener( MouseEvent.MOUSE_MOVE , mouseMoveHandler );
                removeEventListener( MouseEvent.MOUSE_UP , mouseUpHander );             
                
            }   
        }
    }
}

Labels: actionscript, flash, mouse gesture

Labels: actionscript

Labels: actionscript, air, fanfou, flash

Labels: actionscript, flash, spectrum

package {
   import fl.controls.Button;
   import flash.display.*;
   import flash.events.*;
   import flash.net.*;
   import flash.media.Sound;
   import flash.media.SoundChannel;
   import flash.text.TextField;
   import flash.text.TextFieldType;
   import flash.events.TextEvent;
   public class Text2speech01 extends Sprite {
      private const API_URL:String = "http://api.satoru.net/text2voice/";
      private var urlReq:URLRequest = new URLRequest(API_URL);
      private var urll:URLLoader = new URLLoader();
      private var v:URLVariables = new URLVariables();
      public var textInputTxt:TextField;     
      function Text2speech01() {
         init();
      }
      private function init():void {
         var myButton:Button = new Button();
         textInputTxt = new TextField();
         textInputTxt.addEventListener(TextEvent.TEXT_INPUT, textInputHandler);
         textInputTxt.type = TextFieldType.INPUT;
         textInputTxt.background = true;
         textInputTxt.border = true;
         textInputTxt.height=20;
         textInputTxt.width=300;
         textInputTxt.x=10;
         textInputTxt.y=18;
         textInputTxt.text="Long long ago, there is a girl."
         v.text = "Long long ago, there is a girl.";
         addChild(textInputTxt);
         myButton.label = "saying";
         //myButton.emphasized = true;
         myButton.width = 80;
         myButton.move(10, 50);
         addChild(myButton);
         myButton.addEventListener(MouseEvent.CLICK, buttonClick);
         textInputTxt.addEventListener(MouseEvent.MOUSE_OVER,changeStyle1);
         textInputTxt.addEventListener(MouseEvent.MOUSE_OUT,changeStyle2);
      }
      private function changeStyle1(e:MouseEvent):void{
           textInputTxt.borderColor= 0x00FF00;
      }
      private function changeStyle2(e:MouseEvent):void{
                 textInputTxt.borderColor= 0x000000;
      }
      private function textInputHandler(e:TextEvent):void {
             v.text= textInputTxt.text+e.text;
         //trace(">> e.text: " + e.text);
         //trace(">> textInputTxt.text: " + v.text);
      }
        private function buttonClick(e:MouseEvent) {       
         urlReq.data = v;
         urlReq.method = URLRequestMethod.GET;
         trace("urlReq is :"+urlReq.data);
         urll.load(urlReq);
         urll.addEventListener(Event.COMPLETE, function(e:Event):void {        
                         trace("API COMPLETE : " + urll.data);
                                  var sreq:URLRequest = new URLRequest(urll.data);
                         var sf:Sound = new Sound();
                         sf.addEventListener(Event.COMPLETE, function(e:Event):void {
                             trace("Sound load COMPLETE"); 
                         });                
                         sf.load(sreq);
                                var sc:SoundChannel = sf.play();

                         sc.addEventListener(Event.SOUND_COMPLETE, function(e:Event):void {
                             trace("Sound play COMPLETE");
                         });
                         
                     });
        }
   }
}

Labels: actionscript, flash

Labels: actionscript